AppleScript ACSR_ExportAILayers2EPS_CS2

Verwendung

Script zum Export von Illustrator-Ebenen als einzelne Dateien im Illustrator EPS-Format mit dem Namen der Ebene. Hierdurch kann vorteilhaft ein Masterdokument erstellt werden, dass alle Stilvorlagen, Pinsel und Farbdefinitionen enthält und alle Varianten der benötigten Illustrationen als separate Ebene beherbergt. Änderungen können nun global angewendet und hunderte Dateien aktualisiert exportiert werden. Wenn vorher die Metadaten (FileInfo) des Masters aktualisiert werden, können Revisionen sehr leicht nachvollzogen werden.

Version / Copyright

Version 070323-3.0.1 -- © 2003-2007 Copyright by acsr industrialdesign, Armin Carl Stroß-Radschinski – all rights-reserved.

Voraussetzungen:

• Illustrator 12.0.3 Mac unter MacOSX 10.4.8 mit installiertem Applescript
• Ein einziges Illustrator-Dokument geöffnet
• Der Ebenen-Name wird zur Erzeugung des Dateinamens der Einzeldateien verwendet. Dabei findet keine Konformitätsprüfung statt! Es sollten im Ebenennamen keine unzulässigen Sonderzeichen oder Umlaute benutzt werden und möglichst nur solche, die auch auf den anderen geplanten Plattformen funktionieren (":/*&, etc"). Es bleiben z.B. für eine Rückwärtskompatibilität zu OS9 max 27 Zeichen (zzgl. 4 Zeichen für die Endung ".eps") für den Ebenennamen.
• Die oberste Ebene (üblicherweise "BoundingBox") sollte einen unsichtbaren Rahmen enthalten. Diese oberste Ebene wird in allen EPS-Dateien mitgesichert und sichert den standgenauen Re-Import nach Änderungen an den Dateien. Der Rahmen wird vorteilhaft so groß angelegt, dass alle Varianten in diesen einen Rahmen passen. Sind verschiedene Begrenzungs-Rahmen sinnvoll, bleibt diese Ebene leer und jede Exportebene erhält eine eigene "BoundingBox". Wichtig für den Scriptbenutzer ist, dass die erste Ebene immer zusammen mit der vereinzelten Folgeebene gesichert wird. Es können dort auch unsichtbare Copyrightvermerke etc. untergebracht werden.
  

Systemvoraussetzungen

MacOSX 10.4, AppleScript,  Illustrator CS2.

Installation

Installation im Ordner Vorgaben/Scripte der Illustrator Installation oder separater Aufruf im Scripteditor.

Quellcode

-- Scriptname "ACSR_ExportAILayers2EPS_CS2"
-- Version 070323-3.0.1
-- Copyright by acsr industrialdesign Armin Carl Stroß-Radschinski


-- Script zum Export von Illustrator-Ebenen als einzelne Dateien im Illustrator EPS-Format mit dem Namen der Ebene

(*
Eigentumsvorbehalt
Dieser Code bleibt Eigentum des Autors. Es handelt sich um einen Entwicklungsprototypen ohne Funktionsgarantie. Jede Verwendung erfolgt auf eigene Gefahr. Der Inhalt ist nicht veröffentlich im Sinne des Urheberrechts. Ohne die  ausdrückliche Genehmigung des Autors darf sie weder komplett, in Teilen Kopien, Auszügen, Übertragungen oder anderen Verfahren die dem Zweck der Kommunikation des Inhalts dienen, Dritten zugänglich gemacht werden ohne den vollständigen Wortlaut dieser Notiz als ausdrücklichen Hinweis in die Nachricht mit aufzunehmen. Grundsätzlich ist der Inhalt im Zweifel als geheimhaltungswürdig anzusehen und daher ist Stillschweigen darüber zu wahren.
Der Code darf nur zur Erzielung des mit der Übergabe verbundenenen Zwecks verwendet werden. Arbeitskopien dürfen nur entsprechend den oben genannten Bedingungen erstellt werden und sind wie Originale zu Handhaben. Wird der Code an Dritte mit der Ausführung von Dienstleistungen betraute weitergegeben haftet, der Überbringer für Verstöße des Dritten direkt gegenüber dem Autor.
Der Benutzer erkennt diese Bedingung mit der Ausführung des Codes an. 
Sollte die Bedingung nicht akzeptabel sein ist der Code sofort mit Hinweis auf die Verweigerung der Annahme auf den Originaldatenträger zurückzugeben oder entsprechend den Datenschutzbestimmungen zu vernichten. In jedem Falle gilt die Stillschweigeverpflichtung unabhängig davon weiter.
Bekannte Probleme der vorläufigen Version:


Voraussetzungen:
- Illustrator 12.0.3 Mac unter MacOSX 10.4.8 mit installiertem Applescript 
- Ein einziges Illustrator-Dokument geöffnet
- Die oberste Ebene (üblicherweise "BoundingBox") sollte unsichtbaren Rahmen enthalten. Diese oberste Ebene wird in allen 
EPS-Dateien mitgesichert. 
- Der Ebenen-Name wird zur Erzeugung des Dateinamens der Einzeldateien verwendet. 

Dabei findet keine Konformitätsprüfung statt! Es bleiben für die Rückwärtskompatibilität zu OS9 somit 27 Zeichen (zzgl. 4 Zeichen für die Endung ".eps") für den Ebenennamen. Es sollten keine unzulässigen Zeichen benutzt werden und möglichst nur solche die auch auf den anderen Plattformen funktionieren  (":/*&,etc")

Änderungen 2007-03-23

Anpassung an Illustrator CS2

Änderungen 2004-10-30

Abfrage des Exportpfades mit Dialog

Änderungen 2004-08-13

Optionen beim Speichern vollständig definiert (4800 DPI Auflösung!).
Nun werden Schriften und verknüpfte Dateien ordnungsgemäß eingebettet
Speicherformat ist nun AI10

- Der Speicherort ist zur Zeit recht willkürlich. Unter OSX 10.3.5 findet man z.Zt. die Dateien 
meist innerhalb des Ordners "/Library/Application\ Support/Adobe/Fonts/Reqrd/CMaps" 
oder (Wenn AI10 als OS9 Applikation installiert ist innerhalb des Illustrator Programmpaketes. 
Sherlock findet Sie dort leider nicht. 
- Um an die Dateien zu gelangen, öffnet man das Package mit Control/Mausklick über das
Kontextmenü "Paketinhalt zeigen". Dort in den Ordner "Content/MacOSClassic" sehen und 
nach "Art" sortieren und die benötigten Dateien z.B. auf den Schreibtisch verschieben.
- Dort befinden sich ebenfalls die temporären Dateien "Temp.ai", "TempBlanko.ai" und 
"Masterbak.ai" die während der Entwicklungphase zur leichteren Fehlersuche nicht gelöscht werden.
- Der Speicherort unter Classic bzw. OS9 ist z.Zt. nicht dokumentiert und muß nachgetragen werden
*)
--   Anzeigen der Optionen
display dialog ¬
	"Script ACSR_ExportAILayers2EPS_CS2 
	Version 070323-3.0.1 
	Sichere Ebenen mit Einbettung aller 
	Schriften und Bilder im AI12 EPS Format" buttons {"Weiter"} default button "Weiter"

--	Abfrage des Ablageortes für die exportierten Dateien
set targetFolder to choose folder with prompt "Pfad für exportierte Dateien"

--	Umwandlung des Pfades in einen String zur späteren Verwendung
tell application "Finder" to ¬
	set targetPath to item targetFolder as string

--   Beginn der Exportsequenz
with timeout of 600 seconds
	tell application "Adobe Illustrator"
		-- Abschalten der Benutzerinteraktion, damit keine Dialoge das Script unterbrechen können
		
		set user interaction level to interact with local
		-- set user interaction level to never interact
		
		activate
		set MasterDoc to current document
		set LayerCountMaster to (count of layers of MasterDoc)
		
		if LayerCountMaster > 2 then
			-- not necessary for cs2 : set properties of MasterDoc to {name:"Masterbak", output resolution:4800}
			repeat with counter from 1 to LayerCountMaster
				set properties of layer counter of MasterDoc to {visible:true}
			end repeat
			save MasterDoc in file "Temp.ai"
			save MasterDoc in file "Masterbak.ai"
			open file "Temp.ai"
			set properties of current document to {name:"TempBlanko"}
			set TempDoc to current document
			set LayerCountTemp to (count of layers of TempDoc)
			repeat with counter from 2 to LayerCountTemp
				delete layer 2 of current document
			end repeat
			save current document in file ¬
				"TempBlanko.ai"
			
			repeat with counter from 2 to LayerCountMaster
				set LayerName to name of layer counter of document 2 as string
				set LastLayer to count of layers of document 1
				set NewLayer to make new layer at after layer LastLayer of document 1 with properties {name:LayerName}
				set pageItemRef to duplicate every page item of layer counter of document 2 to end of document 1
				set ExportFileName to LayerName & ".eps"
				save document 1 in file (targetPath & ExportFileName) as eps ¬
					with options {class:EPS save options ¬
					, CMYK PostScript:true ¬
					, compatibility:Illustrator 12 ¬
					, embed all fonts:true ¬
					, PostScript:level 2 ¬
					, preview:color Macintosh ¬
					, embed linked files:true ¬
					, overprint:preserve ¬
					, include document thumbnails:true}
				delete layer LayerName of document 1
			end repeat
			set the clipboard to {}
			close TempDoc saving no
			close MasterDoc saving no
			display dialog ¬
				"Script ACSR_ExportAILayers2EPS_CS2
				erfolgreich beendet" buttons {"Fertig"} default button "Fertig"
		end if
	end tell
end timeout