Artikelaktionen

Wie installiere ich unter MacOSX das unter Linux beliebte Perl-Script "rename" / "prename"?

Das Perl-Script "rename" / "prename" kann in Verbindung mit dem find Befehl rekursiv verwendet werden um Dateinamen global zu manipulieren ohne wie der mv Befehl die Daten ggf. zu kopieren und zu löschen. Rename ist also in der Rgel sicherer, wenn die Daten nicht verloren gehen sollen/dürfen.

Bedingungen

Perl muss auf der Box verfügbat sein.
Wenn kein aktuelles Perl 5.8 oder 5.9 verfügbar ist, muss es z.B. mit MacPorts nachinstalliert werden.
Dazu wird die aktuelle MacPorts Installation (jeweils für für Panther, Tiger oder Leopard spezifisch) benötigt.
1. MacPorts downloaden
2. Mit PKG installieren
Unter MacOSX 10.4 kann unter Umständen die automatische Anpassung der .profile Datei für die Shell / das Terminal misslingen. Dann sind die folgenden Schritte von hand auszuführen:
1. Mit "sudo vi /etc/profile" die globale Shell-Startup Datei um die folgende Zeile ergänzen:
```
export PATH="/opt/local/bin:/opt/local/sbin/"":"$PATH
```
  vi mit Escape und :x! verlassen.
2. Neues Terminal Starten und MacPorts updaten
```
sudo port selfupdate
```
3. Nach einer aktuellen perl Installation suchen mit:
```
sudo port search perl
```
4. ggf. mit folgendem Befehl installieren:
```
sudo port install perl 5.8
oder
sudo port install perl 5.9
```
Das folgende Script als ausführbares Script in /usr/bin erzeugen:
```
sudo vi /usr/bin/prename
```

Den folgenden Inhalt nach Drücken von "i" (Insert-Mode) eingeben:

#!/usr/bin/perl -w
#
#  This script was developed by Robin Barker (Robin.Barker@npl.co.uk),
#  from Larry Wall's original script eg/rename from the perl source.
#
#  This script is free software; you can redistribute it and/or modify it
#  under the same terms as Perl itself.
#
# Larry(?)'s RCS header:
#  RCSfile: rename,v   Revision: 4.1   Date: 92/08/07 17:20:30 
#
# $RCSfile: rename,v $$Revision: 1.5 $$Date: 1998/12/18 16:16:31 $
#
# $Log: rename,v $
# Revision 1.5  1998/12/18 16:16:31  rmb1
# moved to perl/source
# changed man documentation to POD
#
# Revision 1.4  1997/02/27  17:19:26  rmb1
# corrected usage string
#
# Revision 1.3  1997/02/27  16:39:07  rmb1
# added -v
#
# Revision 1.2  1997/02/27  16:15:40  rmb1
# *** empty log message ***
#
# Revision 1.1  1997/02/27  15:48:51  rmb1
# Initial revision
#

use strict;

use Getopt::Long;
Getopt::Long::Configure('bundling');

my ($verbose, $no_act, $force, $op);

die "Usage: rename [-v] [-n] [-f] perlexpr [filenames]\n"
    unless GetOptions(
	'v|verbose' => \$verbose,
	'n|no-act'  => \$no_act,
	'f|force'   => \$force,
    ) and $op = shift;

$verbose++ if $no_act;

if (!@ARGV) {
    print "reading filenames from STDIN\n" if $verbose;
    @ARGV = <STDIN>;
    chop(@ARGV);
}

for (@ARGV) {
    my $was = $_;
    eval $op;
    die $@ if $@;
    next if $was eq $_; # ignore quietly
    if (-e $_ and !$force)
    {
	warn  "$was not renamed: $_ already exists\n";
    }
    elsif ($no_act or rename $was, $_)
    {
	print "$was renamed as $_\n" if $verbose;
    }
    else
    {
	warn  "Can't rename $was $_: $!\n";
    }
}

__END__

=head1 NAME

rename - renames multiple files

=head1 SYNOPSIS

B<rename> S<[ B<-v> ]> S<[ B<-n> ]> S<[ B<-f> ]> I<perlexpr> S<[ I<files> ]>

=head1 DESCRIPTION

C<rename>
renames the filenames supplied according to the rule specified as the
first argument.
The I<perlexpr> 
argument is a Perl expression which is expected to modify the C<$_>
string in Perl for at least some of the filenames specified.
If a given filename is not modified by the expression, it will not be
renamed.
If no filenames are given on the command line, filenames will be read
via standard input.

For example, to rename all files matching C<*.bak> to strip the extension,
you might say

	rename 's/\.bak$//' *.bak

To translate uppercase names to lower, you'd use

	rename 'y/A-Z/a-z/' *

=head1 OPTIONS

=over 8

=item B<-v>, B<--verbose>

Verbose: print names of files successfully renamed.

=item B<-n>, B<--no-act>

No Action: show what files would have been renamed.

=item B<-f>, B<--force>

Force: overwrite existing files.

=back

=head1 ENVIRONMENT

No environment variables are used.

=head1 AUTHOR

Larry Wall

=head1 SEE ALSO

mv(1), perl(1)

=head1 DIAGNOSTICS

If you give an invalid Perl expression you'll get a syntax error.

=head1 BUGS

The original C<rename> did not check for the existence of target filenames,
so had to be used with care.  I hope I've fixed that (Robin Barker).

=cut

speichern mit Escape :x!
Rechte als ausführbare Datei setzen:
```
sudo chmod 750 /usr/bin/prename
```
Link anlegen:
```
cd /usr/bin/
sudo ln -s prename rename
```
Das sollte es gewesen sein!
rename erfreut mit folgender Syntax-Schablone nach EIngabe des Befehls ohne Argumente:
```
Usage: rename [-v] [-n] [-f] perlexpr [filenames]
```

Beispiel

Umbenennen von ungültigen Bildnamen vor dem Upload in ein CMS (z.B. Plone via WebDAV)

cd Wurzelverzeichnis/der/Umbennnung

find . | rename 's/\(/\@7B/'
find . | rename 's/\)/\@7D/'
find . | rename 's/\[/\@5B/'
find . | rename 's/\]/\@5D/'

Die obige Befehlsfolge ersetzt das jeweisl erste Vorkommen eines der Zeichen "[]()" durch eine abgewandelte Unicode Percent-Umschreibung, bei der das Prozent-Zeichen durch ein (at) ersetzt ist. Dadurch bleibt in der Regel die Ursprungsinformation des Dateinamens umschrieben erhalten. Die Dateien lassen sich jetzt an der Dateinamen-Überprüfung vorbei in Plone hochladen.

Konkret: [ -> @7B

Für jedes Vorkommen ist ein eigener Lauf erforderlich. Wenn also das Zeichen [ max 3 Mal vorkommt, reicht es den Befehl:

find . | rename 's/\[/\@5B/'

mindestens 3x auszuführen. (Ist das Zeitverhalten unkritisch, kann es auch ein Bisschen mehr sein). Das Ganze geht natürlich auch rekursiv, läßt sich aber dann nicht so schön steuern.

(OffTopic) Löschen von Unterverzeichnissen mit Thumbnails

cd Wurzelverzeichnis/der/Löschaktion
rm -Rf ./*/*thumbs

Credits: Timo Stollenwerk für den entscheidenden Tipp zu rename und der Syntax des Aufrufs.

Sektionen

Benutzerspezifische Werkzeuge